runnerdragon/build.gradle.kts

import io.github.patrick.gradle.remapper.RemapTask

plugins {
    kotlin("jvm") version "1.8.21"
    id("com.github.johnrengelman.shadow") version "7.1.2"
    id("io.github.patrick.remapper") version "1.4.0"
}

group = "xyz.atnrch.dragon"
version = "1.0-SNAPSHOT"

repositories {
    mavenLocal()
    maven("https://hub.spigotmc.org/nexus/content/repositories/snapshots/")
    maven("https://oss.sonatype.org/content/repositories/snapshots")
    maven("https://oss.sonatype.org/content/repositories/central")
    maven("https://maven.enginehub.org/repo")
    maven("https://repo.xenondevs.xyz/releases")
}

dependencies {
    // Stdlib
    implementation("org.jetbrains.kotlin:kotlin-stdlib:1.8.10")
    // InvUI
    implementation("xyz.xenondevs.invui:invui:1.11")
    // Commons IO
    implementation("commons-io:commons-io:2.11.0")
    // Spigot
    compileOnly("org.spigotmc:spigot-api:1.20.1-R0.1-SNAPSHOT")
    // WorldEdit
    compileOnly("com.sk89q.worldedit:worldedit-core:7.3.0-SNAPSHOT")
    compileOnly("com.sk89q.worldedit:worldedit-bukkit:7.3.0-SNAPSHOT")
}

kotlin {
    jvmToolchain(17)
}

tasks {
    remap {
        version.set("1.20.1")
        action.set(RemapTask.Action.MOJANG_TO_SPIGOT)
        inputTask.set(shadowJar)
    }
}